mirror of
https://github.com/ksyasuda/SubMiner.git
synced 2026-09-02 11:54:29 -07:00
sudacode
0d66747f2e
- Rebuild lifetime completion after stream watch-state changes - Update release packaging metadata and fast-uri
68 lines
2.7 KiB
Bash
68 lines
2.7 KiB
Bash
# Maintainer: Kyle Yasuda <suda@sudacode.com>
|
|
|
|
pkgname=subminer-bin
|
|
pkgver=0.19.5
|
|
pkgrel=2
|
|
pkgdesc='All-in-one sentence mining overlay with AnkiConnect and dictionary integration'
|
|
arch=('x86_64')
|
|
url='https://github.com/ksyasuda/SubMiner'
|
|
license=('GPL-3.0-or-later')
|
|
options=('!strip' '!debug')
|
|
depends=(
|
|
'bun'
|
|
'fuse2'
|
|
'glibc'
|
|
'mpv'
|
|
'zlib-ng-compat'
|
|
)
|
|
optdepends=(
|
|
'ffmpeg: media extraction and screenshot generation'
|
|
'ffmpegthumbnailer: faster thumbnail previews in the launcher'
|
|
'fzf: terminal media picker in the subminer wrapper'
|
|
'rofi: GUI media picker in the subminer wrapper'
|
|
'chafa: image previews in the fzf picker'
|
|
'yt-dlp: YouTube playback and subtitle extraction'
|
|
'mecab: optional Japanese metadata enrichment'
|
|
'mecab-ipadic: dictionary for MeCab metadata enrichment'
|
|
'python-guessit: improved AniSkip title and episode inference'
|
|
'alass-git: preferred subtitle synchronization engine'
|
|
'python-ffsubsync: fallback subtitle synchronization engine'
|
|
'mangatan-extension-server: anime browser bridge shared with Mangatan; skips the bundle download and is updated by pacman'
|
|
)
|
|
provides=("subminer=${pkgver}")
|
|
conflicts=('subminer')
|
|
source=(
|
|
"SubMiner-${pkgver}.AppImage::https://github.com/ksyasuda/SubMiner/releases/download/v${pkgver}/SubMiner-${pkgver}.AppImage"
|
|
"subminer-${pkgver}::https://github.com/ksyasuda/SubMiner/releases/download/v${pkgver}/subminer"
|
|
"subminer-assets-${pkgver}.tar.gz::https://github.com/ksyasuda/SubMiner/releases/download/v${pkgver}/subminer-assets.tar.gz"
|
|
)
|
|
sha256sums=(
|
|
'bd683d949956ff847927f23acfede49efad6320cf7ec4cdc3cbd586a5287884e'
|
|
'2fa292f672df715461765aef8d5c6bf3612004c8b8070b1b1f0afa10d4b74c1e'
|
|
'591468a1fc68a13de315acaf1154df9da41fe3bcbc0e5522a04ba21e939ed1ae'
|
|
)
|
|
noextract=("SubMiner-${pkgver}.AppImage")
|
|
|
|
package() {
|
|
install -dm755 "${pkgdir}/usr/bin"
|
|
|
|
install -Dm755 "${srcdir}/SubMiner-${pkgver}.AppImage" \
|
|
"${pkgdir}/opt/SubMiner/SubMiner.AppImage"
|
|
install -dm755 "${pkgdir}/opt/SubMiner"
|
|
ln -s '/opt/SubMiner/SubMiner.AppImage' "${pkgdir}/usr/bin/SubMiner.AppImage"
|
|
|
|
install -Dm755 "${srcdir}/subminer-${pkgver}" "${pkgdir}/usr/bin/subminer"
|
|
|
|
install -Dm644 "${srcdir}/config.example.jsonc" \
|
|
"${pkgdir}/usr/share/SubMiner/config.example.jsonc"
|
|
install -Dm644 "${srcdir}/plugin/subminer.conf" \
|
|
"${pkgdir}/usr/share/SubMiner/plugin/subminer.conf"
|
|
install -Dm644 "${srcdir}/assets/themes/subminer.rasi" \
|
|
"${pkgdir}/usr/share/SubMiner/themes/subminer.rasi"
|
|
install -Dm644 "${srcdir}/assets/thumbnailers/subminer-ffmpegthumbnailer.thumbnailer" \
|
|
"${pkgdir}/usr/share/SubMiner/thumbnailers/subminer-ffmpegthumbnailer.thumbnailer"
|
|
|
|
install -dm755 "${pkgdir}/usr/share/SubMiner/plugin/subminer"
|
|
cp -a "${srcdir}/plugin/subminer/." "${pkgdir}/usr/share/SubMiner/plugin/subminer/"
|
|
}
|