sudacode/SubMiner
1
0
Fork 0
mirror of https://github.com/ksyasuda/SubMiner.git synced 2026-03-20 12:11:28 -07:00
Code Issues Packages Projects Releases Wiki Activity

Automate AUR publish in tagged release workflow (#22)

Browse Source
This commit is contained in:
Kyle Yasuda
2026-03-14 19:49:46 -07:00
committed by GitHub
parent 99f4d2baaf
commit 9eed37420e
36 changed files with 641 additions and 722 deletions
Download Patch File Download Diff File Expand all files Collapse all files

36
packaging/aur/subminer-bin/.SRCINFO Normal file
View File

@@ -0,0 +1,36 @@
pkgbase = subminer-bin
pkgdesc = All-in-one sentence mining overlay with AnkiConnect and dictionary integration
pkgver = 0.6.2
pkgrel = 1
url = https://github.com/ksyasuda/SubMiner
arch = x86_64
license = GPL-3.0-or-later
depends = bun
depends = fuse2
depends = glibc
depends = mpv
depends = zlib-ng-compat
optdepends = ffmpeg: media extraction and screenshot generation
optdepends = ffmpegthumbnailer: faster thumbnail previews in the launcher
optdepends = fzf: terminal media picker in the subminer wrapper
optdepends = rofi: GUI media picker in the subminer wrapper
optdepends = chafa: image previews in the fzf picker
optdepends = yt-dlp: YouTube playback and subtitle extraction
optdepends = mecab: optional Japanese metadata enrichment
optdepends = mecab-ipadic: dictionary for MeCab metadata enrichment
optdepends = python-guessit: improved AniSkip title and episode inference
optdepends = alass-git: preferred subtitle synchronization engine
optdepends = python-ffsubsync: fallback subtitle synchronization engine
provides = subminer=0.6.2
conflicts = subminer
noextract = SubMiner-0.6.2.AppImage
options = !strip
options = !debug
source = SubMiner-0.6.2.AppImage::https://github.com/ksyasuda/SubMiner/releases/download/v0.6.2/SubMiner-0.6.2.AppImage
source = subminer::https://github.com/ksyasuda/SubMiner/releases/download/v0.6.2/subminer
source = subminer-assets.tar.gz::https://github.com/ksyasuda/SubMiner/releases/download/v0.6.2/subminer-assets.tar.gz
sha256sums = c91667adbbc47a0fba34855358233454a9ea442ab57510546b2219abd1f2461e
sha256sums = 85050918e14cb2512fcd34be83387a2383fa5c206dc1bdc11e8d98f7d37817e5
sha256sums = 210113be64a06840f4dfaebc22a8e6fc802392f1308413aa00d9348c804ab2a1
pkgname = subminer-bin

64
packaging/aur/subminer-bin/PKGBUILD Normal file
View File

@@ -0,0 +1,64 @@
# Maintainer: Kyle Yasuda <suda@sudacode.com>
pkgname=subminer-bin
pkgver=0.6.2
pkgrel=1
pkgdesc='All-in-one sentence mining overlay with AnkiConnect and dictionary integration'
arch=('x86_64')
url='https://github.com/ksyasuda/SubMiner'
license=('GPL-3.0-or-later')
options=('!strip' '!debug')
depends=(
'bun'
'fuse2'
'glibc'
'mpv'
'zlib-ng-compat'
)
optdepends=(
'ffmpeg: media extraction and screenshot generation'
'ffmpegthumbnailer: faster thumbnail previews in the launcher'
'fzf: terminal media picker in the subminer wrapper'
'rofi: GUI media picker in the subminer wrapper'
'chafa: image previews in the fzf picker'
'yt-dlp: YouTube playback and subtitle extraction'
'mecab: optional Japanese metadata enrichment'
'mecab-ipadic: dictionary for MeCab metadata enrichment'
'python-guessit: improved AniSkip title and episode inference'
'alass-git: preferred subtitle synchronization engine'
'python-ffsubsync: fallback subtitle synchronization engine'
)
provides=("subminer=${pkgver}")
conflicts=('subminer')
source=(
"SubMiner-${pkgver}.AppImage::https://github.com/ksyasuda/SubMiner/releases/download/v${pkgver}/SubMiner-${pkgver}.AppImage"
"subminer::https://github.com/ksyasuda/SubMiner/releases/download/v${pkgver}/subminer"
"subminer-assets.tar.gz::https://github.com/ksyasuda/SubMiner/releases/download/v${pkgver}/subminer-assets.tar.gz"
)
sha256sums=(
'c91667adbbc47a0fba34855358233454a9ea442ab57510546b2219abd1f2461e'
'85050918e14cb2512fcd34be83387a2383fa5c206dc1bdc11e8d98f7d37817e5'
'210113be64a06840f4dfaebc22a8e6fc802392f1308413aa00d9348c804ab2a1'
)
noextract=("SubMiner-${pkgver}.AppImage")
package() {
install -dm755 "${pkgdir}/usr/bin"
install -Dm755 "${srcdir}/SubMiner-${pkgver}.AppImage" \
"${pkgdir}/opt/SubMiner/SubMiner.AppImage"
install -dm755 "${pkgdir}/opt/SubMiner"
ln -s '/opt/SubMiner/SubMiner.AppImage' "${pkgdir}/usr/bin/SubMiner.AppImage"
install -Dm755 "${srcdir}/subminer" "${pkgdir}/usr/bin/subminer"
install -Dm644 "${srcdir}/config.example.jsonc" \
"${pkgdir}/usr/share/SubMiner/config.example.jsonc"
install -Dm644 "${srcdir}/plugin/subminer.conf" \
"${pkgdir}/usr/share/SubMiner/plugin/subminer.conf"
install -Dm644 "${srcdir}/assets/themes/subminer.rasi" \
"${pkgdir}/usr/share/SubMiner/themes/subminer.rasi"
install -dm755 "${pkgdir}/usr/share/SubMiner/plugin/subminer"
cp -a "${srcdir}/plugin/subminer/." "${pkgdir}/usr/share/SubMiner/plugin/subminer/"
}